1633 sujets

Formats, encodage, internationalisation, XML

Comment éviter mode quirk de Ie avec xml/xsl ? (résolu)

Bonjour.
Comment faire pour éviter que Ie passe en mode quirk avec un site xml/xsl. il semble que même quand j'enlève le <?xml version="1.0" encoding="UTF-8"?>, il reste ne mode quirks. Voici un exemple de xsl et xml:
le xsl:
<?xml version="1.0" encoding="UTF-8"?><!DOCTYPE xsl:stylesheet  [
	<!ENTITY nbsp   "&#160;">
	<!ENTITY copy   "&#169;">
	<!ENTITY reg    "&#174;">
	<!ENTITY trade  "&#8482;">
	<!ENTITY mdash  "&#8212;">
	<!ENTITY ldquo  "&#8220;">
	<!ENTITY rdquo  "&#8221;"> 
	<!ENTITY pound  "&#163;">
	<!ENTITY yen    "&#165;">
	<!ENTITY euro   "&#8364;">
]>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<!--  xlst TEMPLATE master -->
<html>
<head>
	<meta http-equiv="content-type" content="text/html; charset=UTF-8" />
	<meta name="author" content="Nathan" />
	<meta name="keywords" content="" />
	<meta name="description" content="" />
	<meta name="robots" content="all" />

	<title>..:: HISTOIRE / GÉOGRAPHIE ::..</title>

	<script type="text/javascript" src="../Inc/fnc.js"></script>
	<link rel="Shortcut Icon" type="image/x-icon" href="../favicon.ico" />
	<style type="text/css" media="all">
		@import "../Css/Style.css";
	</style>

	<!--[if lt IE 7.]>
	<link rel="stylesheet" type="text/css" href="../Css/StyleIE.css"/>
	<![endif]-->
	
	<!--[if IE 7]>
	<link rel="stylesheet" type="text/css" href="../Css/StyleIE7.css"/>
	<![endif]-->

</head>

<body onload="window.defaultStatus='HISTOIRE / GÉOGRAPHIE';" id="HG">

<div id="Contenant">
	<div id="intro">
		<div id="pageHeader">
		</div>
	</div>
	
	<div id="Menu">
		<dl class="menu">
			<dt>Menu</dt>
			<dd><a href="../Fichiers/Sommaire.xml"><span class="aa">&nbsp;</span><span class="bb">Sommaire</span><span class="cc">&nbsp;</span></a></dd>
			<dd><a href="Indexdoc.xml"><span class="aa">&nbsp;</span><span class="bb">Index des documents</span><span class="cc">&nbsp;</span></a></dd>
			<dd><a href="../Pages/Perso.html"><span class="aa">&nbsp;</span><span class="bb">Mes documents</span><span class="cc">&nbsp;</span></a></dd>
		</dl>
	</div>
	  	
	<div id="Page_centre">
	<xsl:if test="chapitre/@ico = 'H'">
		<div class="top_fen_chaph"><p class="titre_fen_h"><xsl:value-of select="chapitre/label"/>&nbsp;•&nbsp;<xsl:value-of select="chapitre/titre"/></p><xsl:if test="chapitre/@ico = 'H'">
			<div class="Chrono">
	  			<a href="../Pdf/{chapitre/@id}_Chrono.swf" target="_Blank"><img src="../Images/Btn/Btn_chrono.png" alt="" /></a>
	        </div>
			</xsl:if>
		</div>
	</xsl:if>
	<xsl:if test="chapitre/@ico = 'G'">
		<div class="top_fen_chapg"><p class="titre_fen_g"><xsl:value-of select="chapitre/label"/>&nbsp;•&nbsp;<xsl:value-of select="chapitre/titre"/></p></div>
	</xsl:if>
    <!-- Affichage en mode Histoire (H)-->
    	<xsl:if test="chapitre/@ico = 'H'">
			<div id="fen_chaph" class="fen_chaph">
        
			<div class="texte_chap">
				<span class="sous_section"><xsl:value-of select="chapitre/section/titre"/></span>
				<!-- début du listing des fiches section -->
                    <xsl:for-each select="chapitre/section/media">
                <div class="{@type}">
					<span class="titre_cadre"><xsl:value-of select="@type"/> <b style="font-size:10px;"></b></span>
					<a href="../Fichiers/{../@id}{@id}_fiche.xml">
					<p>
						<img src="Thumbnails/{../@id}{@id}_TUM.jpg" alt="Image" /><br/>
						<xsl:value-of select="titre"/>
					</p>
					</a>
				</div>
				</xsl:for-each>
				<br/>					
			</div>
		</div>
		<div class="bas_fen_chaph"></div>
        </xsl:if>
     <!-- FIN Affichage en mode histoire (H)-->
    <!-- Affichage en mode Géographie (G)-->
    	<xsl:if test="chapitre/@ico = 'G'">
			<div id="fen_chapg" class="fen_chapg">
			<div class="texte_chap">
				<span class="sous_section"><xsl:value-of select="chapitre/section/titre"/></span>
				<!-- début du listing des fiches section -->
                    <xsl:for-each select="chapitre/section/media">
                <div class="{@type}">
                	
					<span class="titre_cadre"><xsl:value-of select="@type"/> <b style="font-size:10px;"></b></span>
                    <a href="../Fichiers/{../@id}{@id}_fiche.xml">
					<p>
						<img src="Thumbnails/{../@id}{@id}_TUM.jpg" alt="Image" /><br/>
						<xsl:value-of select="titre"/>
					</p>
					</a>
                    
				</div>
				</xsl:for-each>
				<br/>					
			</div>
		</div>
		<div class="bas_fen_chapg"></div>
        </xsl:if>
     <!-- FIN Affichage en mode Géographie (G)-->
	</div>
	
</div>

<div id="Footer">
	<p><img src="../Images/Design/Logo_nathan_small.png" alt="Logo Nathan" />
	<span> <a href="../index.html">Accueil</a>  |  <a href="../Fichiers/Sommaire.xml">Sommaire</a>  |  <a href="Indexdoc.xml">Index des documents</a>  | <a href="../Pages/Perso.html"> Mes documents</a></span>
    </p>
</div>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

et le xml:
<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="../Pages/Chap.xsl"?>
<chapitre ico="H" id="1">
	<label>Chapitre 1</label>
	<titre>La Première Guerre mondiale (1914-1918)</titre>
	<section id="11">
		<titre>Les grandes phases de la guerre</titre>
		<media type="Photo" id="1">
			<titre>L’Union sacrée </titre>
		</media>
		<media type="Texte" id="2">
			<titre>Les États-Unis entrent en guerre </titre>
		</media>
		<media type="Vidéo" id="3">
			<titre>La bataille de Verdun </titre>
		</media>
	</section>
</chapitre>

Merci!
Modifié par Dantahoua (01 Aug 2007 - 00:42)
Il fallait ajouter

<xsl:output method="xml" encoding="UTF-8" doctype-public='-//W3C//DTD XHTML 1.0 Strict//EN' omit-xml-declaration='yes' media-type="text/xml"/>

entre

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
et
<xsl:template match="/">

et surtout mettre omit-xml-declaration='yes' pour eviter de mettre IE en mode 'quirks' (l'empechant ainsi de bien gérer les css) et pour forcer le document en XHTML.

Pour les conditions il fallait aussi faire:

<xsl:comment><![CDATA[
[if lt IE 7.]>
<link rel="stylesheet" type="text/css" href="../Css/StyleIE.css"/>
<![endif]]]>
</xsl:comment>
<xsl:comment><![CDATA[
[if IE 7]>
<link rel="stylesheet" type="text/css" href="../Css/StyleIE7.css"/>
<![endif]]]>
</xsl:comment>

Mais maintenant c'est dans Firefox que ca ne marche plus, il ne tient plus compte du tout du xsl... Smiley fache
Une idée?
Bon suffisait juste de rajouter xmlns="http://www.w3.org/1999/xhtml" dans <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

Maintenant, rest plus que IE7 qui chie... y prend pas en compte ma css commentaire...
Une idée ?
Voici ce que j'ai fait et ca marche nikel maintenant... Attention ne pas mettre de retour chariot après le CDATA sinon ca ne marche pas...
<xsl:if test="system-property('xsl:vendor') = 'Microsoft'">
	<xsl:comment><![CDATA[[if lt IE 7.0]>
	<link rel="stylesheet" type="text/css" media="screen" href="../Css/StyleIE.css"/>
    <![endif]]]></xsl:comment>
	<xsl:comment><![CDATA[[if IE 7]>
	<link rel="stylesheet" type="text/css" media="screen" href="../Css/StyleIE7.css"/>
	<![endif]]]></xsl:comment>
	</xsl:if>

Merci pour votre aide Smiley cligne . C'est bien la première fois que je m'auto-répond à ce point... Je suis seul sur terre... Smiley confus
J'espère que cela servira à quelqu'un!! Smiley biggrin
Sujet clos
Aller à